Помогите с расписанием регл

Михаил_, Florist, okmail, Fish, vicof, lEvGl, Мультук, vbus, shuhard, Konst1k, Prog_man, boozin, Александр111, dyevgeniy, kir-g, dimanikko, DemonShinji2

☑

0 Florist

14.05.25

✎

19:34

У меня есть такой код в форме справочника по ТО оборудования, там задается в форме элемента расписание через команду, код который

&НаКлиенте
Процедура НастроитьРасписаниеВыполнить()

    Если ЭтотОбъект.Расписание = Неопределено Тогда
        ЭтотОбъект.Расписание = Новый РасписаниеРегламентногоЗадания();
    Иначе
        Попытка
            Расписание = Новый РасписаниеРегламентногоЗадания();
            Расписание.ИзСтроки(ЭтотОбъект.Расписание);
            ЭтотОбъект.Расписание = Расписание;
        Исключение
            ЭтотОбъект.Расписание = Новый РасписаниеРегламентногоЗадания();
        КонецПопытки;
    КонецЕсли;

    Диалог = Новый ДиалогРасписанияРегламентногоЗадания(ЭтотОбъект.Расписание);
    Диалог.Показать(Новый ОписаниеОповещения("ОткрытьРасписаниеЗавершение", ЭтотОбъект));

КонецПроцедуры

&НаКлиенте
Процедура ОткрытьРасписаниеЗавершение(НовоеРасписание, Контекст) Экспорт

    Если НовоеРасписание = Неопределено Тогда
        Возврат;
    КонецЕсли;
    Объект.Расписание = Строка(НовоеРасписание);
КонецПроцедуры

Как сделать грамотнее, чтобы сохранять нормально расписание и в строку и при этом куда-то еще чтобы потом в обработке использовать данные расписания. Также у меня открывается расписание каждый раз с стандартным значением расписания, даже когда расписание уже задано, как это исправить тоже?

1 Мультук

гуру

14.05.25

✎

20:12

(0)

1) Пожалуйста, не пиши код, который не работает

Расписание.ИзСтроки(ЭтотОбъект.Расписание);

2) ну например, создадим обработку с реквизитом (см рис)

РасписаниеСтрока Строка(0)

&НаКлиенте
Процедура НастроитьРасписание(Команда)
    
    Если ПустаяСтрока(Объект.РасписаниеСтрока) Тогда
        пРасписание = Новый РасписаниеРегламентногоЗадания();
	Иначе
		
		пРасписание = ЗначениеИзСтрокиXML(Объект.РасписаниеСтрока);
		
    КонецЕсли;

    Диалог = Новый ДиалогРасписанияРегламентногоЗадания(пРасписание);
    Диалог.Показать(Новый ОписаниеОповещения("ОткрытьРасписаниеЗавершение", ЭтотОбъект));
    
КонецПроцедуры

&НаКлиенте
Процедура ОткрытьРасписаниеЗавершение(НовоеРасписание, Контекст) Экспорт
    
    Если НовоеРасписание = Неопределено Тогда
        Возврат;
    КонецЕсли;
    Объект.РасписаниеСтрока = ЗначениеВСтрокуXML(НовоеРасписание);
КонецПроцедуры             

&НаСервереБезКонтекста
Функция ЗначениеВСтрокуXML(Значение) Экспорт
	
	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.УстановитьСтроку();
	СериализаторXDTO.ЗаписатьXML(ЗаписьXML, Значение);
	Возврат ЗаписьXML.Закрыть();
КонецФункции

&НаСервереБезКонтекста
Функция ЗначениеИзСтрокиXML(СтрокаXML) Экспорт
	
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(СтрокаXML);
		
	Значение=СериализаторXDTO.ПрочитатьXML(ЧтениеXML);
	Возврат Значение;
	
КонецФункции

2 Florist

14.05.25

✎