Подскажие пожалуйста как наложить условие на поле запроса, являющееся арифметическим значением других полей, т.е

есть запрос

ВЫБРАТЬ РАЗРЕШЕННЫЕ
   ВложенныйЗапрос.Склад КАК Склад,
   ВложенныйЗапрос.Номенклатура КАК Номенклатура,
   ВложенныйЗапрос.КоличествоОстаток КАК КоличествоОстаток,
   ВложенныйЗапрос.КоличествоВРезерве КАК КоличествоВРезерве,
   ВложенныйЗапрос.КоличествоКПередаче КАК КоличествоКПередаче,
   ВложенныйЗапрос.КоличествоОстаток - ВложенныйЗапрос.КоличествоВРезерве - ВложенныйЗапрос.КоличествоКПередаче КАК СвободныйОстаток,
   ВложенныйЗапрос.Номенклатура.ОсновнойПоставщик КАК НоменклатураОсновнойПоставщик,
   ЕСТЬNULL(ЦеныНоменклатурыСрезПоследних.Цена, 0) КАК Цена
ИЗ
   (ВЫБРАТЬ
       ВложенныйЗапрос.Склад КАК Склад,
       ВложенныйЗапрос.Номенклатура КАК Номенклатура,
       СУММА(ВложенныйЗапрос.КоличествоОстаток) КАК КоличествоОстаток,
       СУММА(ВложенныйЗапрос.КоличествоВРезерве) КАК КоличествоВРезерве,
       СУММА(ВложенныйЗапрос.КоличествоКПередаче) КАК КоличествоКПередаче
   ИЗ
       (ВЫБРАТЬ
           ТоварыНаСкладахОстатки.Склад КАК Склад,
           ТоварыНаСкладахОстатки.Номенклатура КАК Номенклатура,
           ТоварыНаСкладахОстатки.КоличествоОстаток КАК КоличествоОстаток,
           0 КАК КоличествоВРезерве,
           0 КАК КоличествоКПередаче
       ИЗ
           РегистрНакопления.ТоварыНаСкладах.Остатки(
                   &ВыбДата,
                   &УсловиеНоменклатура
                       И &УсловиеСклад) КАК ТоварыНаСкладахОстатки
       
       ОБЪЕДИНИТЬ ВСЕ
       
       ВЫБРАТЬ
           ТоварыВРозницеОстатки.Склад,
           ТоварыВРозницеОстатки.Номенклатура,
           ТоварыВРозницеОстатки.КоличествоОстаток,
           0,
           0
       ИЗ
           РегистрНакопления.ТоварыВРознице.Остатки(
                   &ВыбДата,
                   &УсловиеНоменклатура
                       И &УсловиеСклад) КАК ТоварыВРозницеОстатки
       
       ОБЪЕДИНИТЬ ВСЕ
       
       ВЫБРАТЬ
           ТоварыВРезервеНаСкладахОстатки.Склад,
           ТоварыВРезервеНаСкладахОстатки.Номенклатура,
           0,
           ТоварыВРезервеНаСкладахОстатки.КоличествоОстаток,
           0
       ИЗ
           РегистрНакопления.ТоварыВРезервеНаСкладах.Остатки(
                   &ВыбДата,
                   &УсловиеНоменклатура
                       И &УсловиеСклад) КАК ТоварыВРезервеНаСкладахОстатки
       
       ОБЪЕДИНИТЬ ВСЕ
       
       ВЫБРАТЬ
           ТоварыКПередачеСоСкладовОстатки.Склад,
           ТоварыКПередачеСоСкладовОстатки.Номенклатура,
           0,
           0,
           ТоварыКПередачеСоСкладовОстатки.КоличествоОстаток
       ИЗ
           РегистрНакопления.ТоварыКПередачеСоСкладов.Остатки(
                   &ВыбДата,
                   &УсловиеНоменклатура
                       И &УсловиеСклад) КАК ТоварыКПередачеСоСкладовОстатки) КАК ВложенныйЗапрос
   
   СГРУППИРОВАТЬ ПО
       ВложенныйЗапрос.Склад,
       ВложенныйЗапрос.Номенклатура) КАК ВложенныйЗапрос
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
               &ВыбДата,
               &УсловиеНоменклатура
                   И ТипЦен = &ВыбТипЦен) КАК ЦеныНоменклатурыСрезПоследних
       ПО ВложенныйЗапрос.Номенклатура = ЦеныНоменклатурыСрезПоследних.Номенклатура
ГДЕ
   &УсловиеПоставщик

УПОРЯДОЧИТЬ ПО
   Номенклатура ИЕРАРХИЯ УБЫВ


Как отобрать все отрицательные остатки по полю "СвободныйОстаток"?

в

ГДЕ
   &УсловиеПоставщи

добавить
B СвободныйОстаток < 0

(1)
в

ГДЕ
   &УсловиеПоставщи

добавить
И СвободныйОстаток < 0

(1) пробывал, не работает так, пишет поле не найдено "СвободныйОстаток"

И (ВложенныйЗапрос.КоличествоОстаток - ВложенныйЗапрос.КоличествоВРезерве - ВложенныйЗапрос.КоличествоКПередаче<0)

(4) спасибо. Работает. Стормоизил, что то я что так можно сделать.