Переделываю обработку загрузки из текстового файла, который был сделан для 7.7. Не могу найти Аналог .ИзСтрокиСРазделителями() для перевода строки табличного документа в список значений.
В 7.7. было:
Для н = 1 По ТХТ.КоличествоСтрок() Цикл
Стр = ТХТ.ПолучитьСтроку(н);
СЗ.ИзСтрокиСРазделителями(Стр);
//ну и далее Код = СЗ.ПолучитьЗначение(1) и т.д.
КонецЦикла;

пока придумал корявое решение через массив
Масс = Новый Массив;
Масс.Очистить();
Для н = 1 по ТХТ.КоличествоСтрок() Цикл
       Стр = СтрЗаменить(ТХТ.ПолучитьСтроку(н),"""","");
       Пока Найти(Стр,",") Цикл
           Поз = Найти(Стр,",");
           Масс.Добавить(Лев(Стр,Поз-1));
           Стр = Прав(Стр, СтрДлина(Стр)-Поз);
       КонецЦикла;
       Масс.Добавить(Лев(Стр,Поз-1));
       
       Код = Масс.Получить(0);

СтрЗаменить(ТХТ.ПолучитьСтроку(н),",",Символы.ПС) и потом выбирай из многострочной строки

Функция ПолучитьМассивСтрок(String, Separator) Экспорт
   
   ArrayRow = New Array();
   
   Lit = "";
   
   For i = 1 To StrLen(String) Do
       
       Character = Mid(String, i, 1);
       
       If Character = Separator Then
           ArrayRow.Add(Lit);
           Lit = "";
       Else
           Lit = Lit + Character;
       EndIf;
   EndDo;
   ArrayRow.Add(Lit);
   
   Return ArrayRow;

КонецФункции


// Функция "расщепляет" строку на подстроки, используя заданный
//        разделитель. Разделитель может иметь любую длину.
//        Если в качестве разделителя задан пробел, рядом стоящие пробелы
//        считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр
//        игнорируются.
//        Например,
//        РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов,
//        три из которых - пустые строки, а
//        РазложитьСтрокуВМассивПодстрок(" ку   му", " ") возвратит массив значений из двух элементов
//
//    Параметры:
//        Стр -            строка, которую необходимо разложить на подстроки.
//                        Параметр передается по значению.
//        Разделитель -    строка-разделитель, по умолчанию - запятая.
//
//
//    Возвращаемое значение:
//        массив значений, элементы которого - подстроки
//
Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт
   
   МассивСтрок = Новый Массив();
   Если Разделитель = " " Тогда
       Стр = СокрЛП(Стр);
       Пока Истина Цикл
           Поз = Найти(Стр,Разделитель);
           Если Поз=0 Тогда
               МассивСтрок.Добавить(Стр);
               Возврат МассивСтрок;
           КонецЕсли;
           МассивСтрок.Добавить(Лев(Стр,Поз-1));
           Стр = СокрЛ(Сред(Стр,Поз));
       КонецЦикла;
   Иначе
       ДлинаРазделителя = СтрДлина(Разделитель);
       Пока Истина Цикл
           Поз = Найти(Стр,Разделитель);
           Если Поз=0 Тогда
               МассивСтрок.Добавить(Стр);
               Возврат МассивСтрок;
           КонецЕсли;
           МассивСтрок.Добавить(Лев(Стр,Поз-1));
           Стр = Сред(Стр,Поз+ДлинаРазделителя);
       КонецЦикла;
   КонецЕсли;
   
КонецФункции // глРазложить



(C) 1С

v8: Покритикуйте код

тама есть код в одну строку чтоб разложить в массив строку :)

спасибо всем.
В 7.7. было 3 строки, в 8.х куча

(6) в 8-ке одна строка. кури (5)