Не открывается типовой запрос. КА

Добрый день.
В комплексной автоматизации есть типовая печатная форма Торг12, мне необходимо сделать на основе нее внешнюю печатную форму. Проблема в том, что сам типовой запрос, которым получаются все данные, не открывается конструктором запроса.

Код процедуры :

Функция ПолучитьДанныеДляПечатнойФормыТОРГ12(ПараметрыПечати, МассивОбъектов) Экспорт

    КолонкаКодов = ФормированиеПечатныхФорм.ИмяДополнительнойКолонки();
    Если Не ЗначениеЗаполнено(КолонкаКодов) Тогда
        КолонкаКодов = "Код";
    КонецЕсли;

    МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;

    Запрос = Новый Запрос;
    Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
    Запрос.Текст = "
    |ВЫБРАТЬ
    |    ДанныеДокументов.Ссылка               КАК Ссылка,
    |    ДанныеДокументов.Валюта               КАК Валюта
    |
    |ПОМЕСТИТЬ ТаблицаДанныхДокументов
    |ИЗ
    |    Документ.РеализацияТоваровУслуг КАК ДанныеДокументов
    |
    |ГДЕ
    |    ДанныеДокументов.Ссылка В (&МассивОбъектов)
    |
    |ИНДЕКСИРОВАТЬ ПО
    |    Ссылка
    |;";
    Запрос.УстановитьПараметр("МассивОбъектов", МассивОбъектов);

    Запрос.Выполнить();

    ПараметрыЗаполнения = ПродажиСервер.ПараметрыЗаполненияВременнойТаблицыТоваров();
    Если ПараметрыПечати.Свойство("ВыводитьГТД") Тогда
        ПараметрыЗаполнения.ВключаяНомераГТД = ПараметрыПечати.ВыводитьГТД;
    КонецЕсли;
    ПоместитьВременнуюТаблицуТоваров(МенеджерВременныхТаблиц, ПараметрыЗаполнения);

    ПродажиСервер.ПоместитьВременнуюТаблицуКоэффициентыУпаковок(МенеджерВременныхТаблиц, "РеализацияТоваровУслугТаблицаТоваров");
    ОтветственныеЛицаСервер.СформироватьВременнуюТаблицуОтветственныхЛицДокументов(МассивОбъектов, МенеджерВременныхТаблиц);

    Запрос.Текст =
    "ВЫБРАТЬ
    |    РеализацияТоваровУслуг.Ссылка КАК Ссылка,
    |    РеализацияТоваровУслуг.Номер КАК Номер,
    |    РеализацияТоваровУслуг.Дата КАК Дата,
    |    РеализацияТоваровУслуг.Статус КАК Статус,
    |    РеализацияТоваровУслуг.Партнер КАК Партнер,
    |    РеализацияТоваровУслуг.Контрагент КАК Контрагент,
    |    ВЫБОР
    |        КОГДА РеализацияТоваровУслуг.Организация.ОбособленноеПодразделение
    |            ТОГДА РеализацияТоваровУслуг.Организация.ГоловнаяОрганизация
    |        ИНАЧЕ РеализацияТоваровУслуг.Организация
    |    КОНЕЦ КАК Организация,
    |    ТаблицаОтветственныеЛица.РуководительНаименование  КАК Руководитель,
    |    ТаблицаОтветственныеЛица.РуководительДолжность КАК ДолжностьРуководителя,
    |    ТаблицаОтветственныеЛица.ГлавныйБухгалтерНаименование КАК ГлавныйБухгалтер,
    |    РеализацияТоваровУслуг.Отпустил КАК Кладовщик,
    |    РеализацияТоваровУслуг.ОтпустилДолжность КАК ДолжностьКладовщика,
    |    РеализацияТоваровУслуг.Организация.Префикс КАК Префикс,
    |    РеализацияТоваровУслуг.Основание КАК Основание,
    |    РеализацияТоваровУслуг.ОснованиеДата КАК ОснованиеДата,
    |    РеализацияТоваровУслуг.ОснованиеНомер КАК ОснованиеНомер,
    |    ВЫБОР
    |        КОГДА РеализацияТоваровУслуг.Грузополучатель = ЗНАЧЕНИЕ(Справочник.Контрагенты.ПустаяСсылка)
    |            ТОГДА РеализацияТоваровУслуг.Контрагент
    |        ИНАЧЕ РеализацияТоваровУслуг.Грузополучатель
    |    КОНЕЦ КАК Грузополучатель,
    |    ВЫБОР
    |        КОГДА РеализацияТоваровУслуг.Грузоотправитель = ЗНАЧЕНИЕ(Справочник.Контрагенты.ПустаяСсылка)
    |            ТОГДА РеализацияТоваровУслуг.Организация
    |        ИНАЧЕ РеализацияТоваровУслуг.Грузоотправитель
    |    КОНЕЦ КАК Грузоотправитель,
    |    РеализацияТоваровУслуг.БанковскийСчетОрганизации КАК БанковскийСчетОрганизации,
    |    РеализацияТоваровУслуг.БанковскийСчетКонтрагента КАК БанковскийСчетКонтрагента,
    |    РеализацияТоваровУслуг.БанковскийСчетГрузоотправителя КАК БанковскийСчетГрузоотправителя,
    |    РеализацияТоваровУслуг.БанковскийСчетГрузополучателя КАК БанковскийСчетГрузополучателя,
    |    РеализацияТоваровУслуг.АдресДоставки КАК АдресДоставки,
    |    НЕОПРЕДЕЛЕНО КАК Подразделение,
    |    РеализацияТоваровУслуг.Валюта КАК Валюта,
    |    РеализацияТоваровУслуг.НалогообложениеНДС КАК НалогообложениеНДС,
    |    РеализацияТоваровУслуг.ДоверенностьНомер КАК ДоверенностьНомер,
    |    РеализацияТоваровУслуг.ДоверенностьДата КАК ДоверенностьДата,
    |    РеализацияТоваровУслуг.ДоверенностьВыдана КАК ДоверенностьВыдана,
    |    РеализацияТоваровУслуг.ДоверенностьЛицо КАК ДоверенностьЛицо,
    |    &ЕдиницаИзмеренияВеса КАК ЕдиницаИзмеренияВеса
    |ИЗ
    |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТаблицаДанныхДокументов КАК ДанныеДокументов
    |        ПО РеализацияТоваровУслуг.Ссылка = ДанныеДокументов.Ссылка
    |        ЛЕВОЕ СОЕДИНЕНИЕ ТаблицаОтветственныеЛица КАК ТаблицаОтветственныеЛица
    |        ПО РеализацияТоваровУслуг.Ссылка = ТаблицаОтветственныеЛица.Ссылка
    |
    |УПОРЯДОЧИТЬ ПО
    |    Ссылка
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////

    |ВЫБРАТЬ
    |    ТаблицаТоваров.Ссылка                КАК Ссылка,
    |    ТаблицаТоваров.НоменклатураНабора    КАК НоменклатураНабора,
    |    ТаблицаТоваров.ХарактеристикаНабора  КАК ХарактеристикаНабора,
    |    МИНИМУМ(ТаблицаТоваров.НомерСтроки)  КАК НомерСтроки,
    |    СУММА(ВЫБОР
    |        КОГДА &ЗаполненаЕдиницаИзмеренияВеса
    |            ТОГДА ВЫБОР
    |                    КОГДА ТаблицаТоваров.Упаковка.Вес ЕСТЬ NULL
    |                        ТОГДА ТаблицаТоваров.Количество
    |                    ИНАЧЕ ВЫБОР
    |                            КОГДА ТаблицаТоваров.Упаковка.ТипИзмеряемойВеличины = Значение(Перечисление.ТипыИзмеряемыхВеличин.Вес)
    |                                ТОГДА 0
    |                            ИНАЧЕ ТаблицаТоваров.КоличествоУпаковок
    |                        КОНЕЦ
    |                КОНЕЦ * &ТекстЗапросаВесУпаковки
    |        ИНАЧЕ 0
    |    КОНЕЦ) КАК МассаБрутто,
    |    СУММА(ТаблицаТоваров.Количество * &ТекстЗапросаВесНоменклатуры) КАК МассаНетто,
    |    СУММА(ТаблицаТоваров.СуммаБезНДС)    КАК СуммаБезНДС,
    |    СУММА(ТаблицаТоваров.СуммаНДС)       КАК СуммаНДС
    |ПОМЕСТИТЬ ВременнаяТаблицаНаборыПодготовка
    |ИЗ
    |    РеализацияТоваровУслугТаблицаТоваров КАК ТаблицаТоваров
    |
    |ГДЕ
    |    ТаблицаТоваров.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
    |
    |СГРУППИРОВАТЬ ПО
    |    ТаблицаТоваров.Ссылка,
    |    ТаблицаТоваров.НоменклатураНабора,
    |    ТаблицаТоваров.ХарактеристикаНабора
    |
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    Товары.Ссылка                                    КАК Ссылка,
    |    Товары.ВариантКомплектацииНоменклатуры           КАК ВариантКомплектацииНоменклатуры,
    |    Товары.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
    |    Товары.ВариантРасчетаЦеныНабора                  КАК ВариантРасчетаЦеныНабора,
    |    Товары.НоменклатураНабора,
    |    Товары.ХарактеристикаНабора,
    |    Товары.Номенклатура,
    |    Товары.Характеристика,
    |    ВЫБОР КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
    |        И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика ТОГДА
    |        ИСТИНА
    |    ИНАЧЕ
    |        ЛОЖЬ
    |    КОНЕЦ КАК ОсновнаяКомплектующая,
    |    Товары.СтавкаНДС КАК СтавкаНДС,
    |    ВЫБОР КОГДА Товары.ВариантКомплектацииНоменклатуры.НоменклатураОсновногоКомпонента = Товары.Номенклатура
    |        И Товары.ВариантКомплектацииНоменклатуры.ХарактеристикаОсновногоКомпонента = Товары.Характеристика ТОГДА
    |        Товары.НомерГТД
    |    ИНАЧЕ
    |        null
    |    КОНЕЦ КАК НомерГТД,
    |    0 КАК КоличествоПоУмолчанию,
    |    Товары.Количество КАК Количество
    |ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительноЧастьПервая
    |ИЗ
    |    РеализацияТоваровУслугТаблицаТоваров КАК Товары
    |
    |ГДЕ
    |    Товары.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ
    |    Т.Ссылка                                                                                КАК Ссылка,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка                                           КАК ВариантКомплектацииНоменклатуры,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка.ВариантРасчетаЦеныНабора                  КАК ВариантРасчетаЦеныНабора,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка.Владелец                                  КАК НоменклатураНабора,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка.Характеристика                            КАК ХарактеристикаНабора,
    |    ВариантыКомплектацииНоменклатурыТовары.Номенклатура   КАК Номенклатура,
    |    ВариантыКомплектацииНоменклатурыТовары.Характеристика КАК Характеристика,
    |    ЛОЖЬ КАК ОсновнаяКомплектующая,
    |    NULL КАК СтавкаНДС,
    |    NULL КАК НомерГТД,
    |    СУММА(ВариантыКомплектацииНоменклатурыТовары.Количество) КАК КоличествоПоУмолчанию,
    |    0 КАК Количество
    |ИЗ
    |    Справочник.ВариантыКомплектацииНоменклатуры.Товары КАК ВариантыКомплектацииНоменклатурыТовары
    |        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ РАЗЛИЧНЫЕ Т.Ссылка ИЗ РеализацияТоваровУслугТаблицаТоваров КАК Т) КАК Т
    |        ПО ИСТИНА
    |ГДЕ
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка В (ВЫБРАТЬ Т.ВариантКомплектацииНоменклатуры ИЗ РеализацияТоваровУслугТаблицаТоваров КАК Т)
    |
    |СГРУППИРОВАТЬ ПО
    |    Т.Ссылка,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка.Владелец,
    |    ВариантыКомплектацииНоменклатурыТовары.Ссылка.Характеристика,
    |    ВариантыКомплектацииНоменклатурыТовары.Номенклатура,
    |    ВариантыКомплектацииНоменклатурыТовары.Характеристика,
    |    ВариантыКомплектацииНоменклатурыТовары.Упаковка
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    Таблица.Ссылка,
    |    Таблица.ВариантКомплектацииНоменклатуры,
    |    Таблица.ВариантРасчетаЦеныНабора,
    |    Таблица.ВариантПредставленияНабораВПечатныхФормах,
    |    Таблица.НоменклатураНабора,
    |    Таблица.ХарактеристикаНабора,
    |    Таблица.Номенклатура,
    |    Таблица.Характеристика,
    |    МАКСИМУМ(Таблица.СтавкаНДС) КАК СтавкаНДС,
    |    МАКСИМУМ(Таблица.НомерГТД) КАК НомерГТД,
    |    МАКСИМУМ(Таблица.ОсновнаяКомплектующая) КАК ОсновнаяКомплектующая,
    |    СУММА(Таблица.КоличествоПоУмолчанию) КАК КоличествоПоУмолчанию,
    |    СУММА(Таблица.Количество) КАК Количество
    |ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительноЧастьВторая
    |ИЗ
    |    ВременнаяТаблицаНаборыДополнительноЧастьПервая КАК Таблица
    |
    |СГРУППИРОВАТЬ ПО
    |    Таблица.Ссылка,
    |    Таблица.ВариантКомплектацииНоменклатуры,
    |    Таблица.ВариантРасчетаЦеныНабора,
    |    Таблица.ВариантПредставленияНабораВПечатныхФормах,
    |    Таблица.НоменклатураНабора,
    |    Таблица.ХарактеристикаНабора,
    |    Таблица.Номенклатура,
    |    Таблица.Характеристика
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    Результат.Ссылка,
    |    Результат.ВариантКомплектацииНоменклатуры,
    |    Результат.ВариантРасчетаЦеныНабора,
    |    Результат.ВариантПредставленияНабораВПечатныхФормах,
    |    Результат.НоменклатураНабора,
    |    Результат.ХарактеристикаНабора,
    |    МАКСИМУМ(ВЫБОР
    |            КОГДА Результат.ОсновнаяКомплектующая
    |                ТОГДА Результат.СтавкаНДС
    |            ИНАЧЕ null
    |        КОНЕЦ) КАК СтавкаНДС,
    |    МАКСИМУМ(Результат.НомерГТД) КАК НомерГТД,
    |    ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
    |            КОГДА Результат.КоличествоПоУмолчанию <> 0 И Результат.ОсновнаяКомплектующая
    |                ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
    |            ИНАЧЕ null
    |        КОНЕЦ) + 0.5 КАК Число(10,0)) - 1 КАК Количество,
    |    МАКСИМУМ(ВЫБОР
    |            КОГДА Результат.КоличествоПоУмолчанию <> 0
    |                ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
    |            ИНАЧЕ null
    |        КОНЕЦ) КАК КоэффициентМаксимум,
    |    ВЫРАЗИТЬ(МИНИМУМ(ВЫБОР
    |            КОГДА Результат.КоличествоПоУмолчанию <> 0
    |                ТОГДА Результат.Количество / Результат.КоличествоПоУмолчанию
    |            ИНАЧЕ null
    |        КОНЕЦ) + 0.5 КАК Число(10,0)) - 1 КАК КоэффициентМинимум
    |ПОМЕСТИТЬ ВременнаяТаблицаНаборыДополнительно
    |ИЗ
    |    ВременнаяТаблицаНаборыДополнительноЧастьВторая КАК Результат
    |СГРУППИРОВАТЬ ПО
    |    Результат.Ссылка,
    |    Результат.ВариантКомплектацииНоменклатуры,
    |    Результат.ВариантРасчетаЦеныНабора,
    |    Результат.ВариантПредставленияНабораВПечатныхФормах,
    |    Результат.НоменклатураНабора,
    |    Результат.ХарактеристикаНабора
    |ИНДЕКСИРОВАТЬ ПО
    |    Ссылка,
    |    НоменклатураНабора,
    |    ХарактеристикаНабора
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    ВременнаяТаблицаНаборыДополнительно.ВариантКомплектацииНоменклатуры,
    |
    |    ВЫБОР КОГДА Таблица.Ссылка.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию) ТОГДА
    |        ВЫБОР КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор) ТОГДА
    |            ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
    |        ИНАЧЕ
    |            ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
    |        КОНЕЦ
    |    ИНАЧЕ
    |        ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
    |    КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
    |
    |    ВЫБОР КОГДА Таблица.Ссылка.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.ПередачаНаКомиссию) ТОГДА
    |        ВЫБОР КОГДА
    |            ВЫБОР КОГДА ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор) ТОГДА
    |                ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
    |            ИНАЧЕ
    |                ВременнаяТаблицаНаборыДополнительно.ВариантПредставленияНабораВПечатныхФормах
    |            КОНЕЦ = ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие)
    |            И ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора В (ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоЦенам),ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ЦенаЗадаетсяЗаНаборРаспределяетсяПоДолям)) ТОГДА
    |                ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.РассчитываетсяИзЦенКомплектующих)
    |        ИНАЧЕ
    |            ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
    |        КОНЕЦ
    |    ИНАЧЕ
    |        ВременнаяТаблицаНаборыДополнительно.ВариантРасчетаЦеныНабора
    |    КОНЕЦ КАК ВариантРасчетаЦеныНабора,
    |
    |    Таблица.Ссылка                            КАК Ссылка,
    |    Таблица.НоменклатураНабора                КАК НоменклатураНабора,
    |    Таблица.ХарактеристикаНабора              КАК ХарактеристикаНабора,
    |    Таблица.НомерСтроки                       КАК НомерСтроки,
    |    ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.НомерГТД, ЗНАЧЕНИЕ(Справочник.НомераГТД.ПустаяСсылка)) КАК НомерГТД,
    |    ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК КоличествоУпаковок,
    |    ЕСТЬNULL(ВременнаяТаблицаНаборыДополнительно.Количество, 1) КАК Количество,
    |    ВЫБОР КОГДА ВременнаяТаблицаНаборыДополнительно.КоэффициентМинимум = ВременнаяТаблицаНаборыДополнительно.КоэффициентМаксимум ТОГДА ИСТИНА ИНАЧЕ ЛОЖЬ КОНЕЦ КАК ПолныйНабор,
    |    Таблица.МассаБрутто                           КАК МассаБрутто,
    |    Таблица.МассаНетто                            КАК МассаНетто,
    |    Таблица.СуммаБезНДС                           КАК СуммаБезНДС,
    |    Таблица.СуммаНДС                              КАК СуммаНДС,
    |    ВременнаяТаблицаНаборыДополнительно.СтавкаНДС КАК СтавкаНДС
    |ПОМЕСТИТЬ ВременнаяТаблицаНаборы
    |ИЗ
    |    ВременнаяТаблицаНаборыПодготовка КАК Таблица
    |        ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборыДополнительно КАК ВременнаяТаблицаНаборыДополнительно
    |        ПО Таблица.НоменклатураНабора = ВременнаяТаблицаНаборыДополнительно.НоменклатураНабора
    |        И Таблица.ХарактеристикаНабора = ВременнаяТаблицаНаборыДополнительно.ХарактеристикаНабора
    |        И Таблица.Ссылка = ВременнаяТаблицаНаборыДополнительно.Ссылка
    |ИНДЕКСИРОВАТЬ ПО
    |    Ссылка,
    |    НоменклатураНабора,
    |    ХарактеристикаНабора
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    ТаблицаТоваров.Ссылка КАК Ссылка,
    |    ТаблицаТоваров.ВариантПредставленияНабораВПечатныхФормах КАК ВариантПредставленияНабораВПечатныхФормах,
    |    ТаблицаТоваров.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
    |    ТаблицаТоваров.НоменклатураНабора КАК НоменклатураНабора,
    |    ТаблицаТоваров.ХарактеристикаНабора КАК ХарактеристикаНабора,
    |    ТаблицаТоваров.ЭтоКомплектующие КАК ЭтоКомплектующие,
    |    ТаблицаТоваров.ЭтоНабор КАК ЭтоНабор,
    |    ТаблицаТоваров.ПолныйНабор КАК ПолныйНабор,
    |    ТаблицаТоваров.Номенклатура КАК Номенклатура,
    |    ТаблицаТоваров.Номенклатура.НаименованиеПолное КАК НоменклатураНаименование,
    |    ТаблицаТоваров.Номенклатура.Наименование КАК НоменклатураНаименованиеКраткое,
    |    ВЫБОР
    |        КОГДА &КолонкаКодов = ""Артикул""
    |            ТОГДА ТаблицаТоваров.Номенклатура.Артикул
    |        ИНАЧЕ ТаблицаТоваров.Номенклатура.Код
    |    КОНЕЦ КАК НоменклатураКод,
    |    ВЫБОР
    |        КОГДА &ВыводитьБазовыеЕдиницыИзмерения
    |            ТОГДА ТаблицаТоваров.Номенклатура.ЕдиницаИзмерения
    |        ИНАЧЕ &ТекстЗапросаЕдиницаИзмерения
    |    КОНЕЦ КАК ЕдиницаИзмерения,
    |    ВЫБОР
    |        КОГДА &ВыводитьБазовыеЕдиницыИзмерения
    |            ТОГДА ТаблицаТоваров.Номенклатура.ЕдиницаИзмерения.Представление
    |        ИНАЧЕ &ТекстЗапросаНаименованиеЕдиницыИзмерения1
    |    КОНЕЦ КАК ЕдиницаИзмеренияНаименование,
    |    ВЫБОР
    |        КОГДА &ВыводитьБазовыеЕдиницыИзмерения
    |            ТОГДА ТаблицаТоваров.Номенклатура.ЕдиницаИзмерения.Код
    |        ИНАЧЕ &ТекстЗапросаКодЕдиницыИзмерения
    |    КОНЕЦ КАК ЕдиницаИзмеренияКод,
    |    ТаблицаТоваров.Характеристика КАК Характеристика,
    |    ТаблицаТоваров.Характеристика.НаименованиеПолное КАК ХарактеристикаНаименование,
    |    ТаблицаТоваров.Упаковка КАК Упаковка,
    |    ВЫБОР
    |        КОГДА ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки, 1) = 1
    |            ТОГДА """"
    |        ИНАЧЕ ТаблицаТоваров.Упаковка.Наименование
    |    КОНЕЦ КАК УпаковкаНаименование,
    |    ВЫБОР
    |        КОГДА &ВыводитьБазовыеЕдиницыИзмерения ТОГДА
    |            &ТекстЗапросаНаименованиеЕдиницыИзмерения1
    |        ИНАЧЕ
    |            &ТекстЗапросаНаименованиеЕдиницыИзмерения2
    |    КОНЕЦ КАК ВидУпаковки,
    |    ТаблицаТоваров.СтавкаНДС КАК СтавкаНДС,
    |    ТаблицаТоваров.НомерГТД КАК НомерГТД,
    |    ТаблицаТоваров.НомерГТД.СтранаПроисхождения КАК СтранаПроисхождения,
    |    ВЫБОР
    |        КОГДА НЕ &ВыводитьБазовыеЕдиницыИзмерения
    |            ТОГДА ТаблицаТоваров.КоличествоУпаковок
    |        ИНАЧЕ ТаблицаТоваров.Количество
    |    КОНЕЦ КАК Количество,
    |    ВЫБОР
    |        КОГДА &ВыводитьБазовыеЕдиницыИзмерения ИЛИ ТаблицаТоваров.ЭтоНабор
    |            ТОГДА ТаблицаТоваров.КоличествоУпаковок
    |        ИНАЧЕ КоэффициентыУпаковок.Количество / КоэффициентыУпаковок.КоэффициентВложеннойУпаковки
    |    КОНЕЦ КАК КоличествоМест,
    |    ВЫБОР
    |        КОГДА НЕ &ВыводитьБазовыеЕдиницыИзмерения И Не ТаблицаТоваров.ЭтоНабор
    |            ТОГДА ВЫБОР
    |                    КОГДА КоэффициентыУпаковок.Количество < КоэффициентыУпаковок.КоэффициентВложеннойУпаковки
    |                        ТОГДА КоэффициентыУпаковок.Количество
    |                    ИНАЧЕ КоэффициентыУпаковок.КоэффициентВложеннойУпаковки
    |                КОНЕЦ
    |        ИНАЧЕ ВЫБОР
    |                КОГДА ТаблицаТоваров.Упаковка = ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка)
    |                    ТОГДА 1
    |                ИНАЧЕ &ТекстЗапросаКоэффициентУпаковки
    |            КОНЕЦ
    |    КОНЕЦ КАК КоличествоВОдномМесте,
    |    ВЫБОР
    |        КОГДА НЕ &ВыводитьБазовыеЕдиницыИзмерения
    |            ТОГДА ТаблицаТоваров.СуммаБезНДС / ТаблицаТоваров.КоличествоУпаковок
    |        ИНАЧЕ ТаблицаТоваров.СуммаБезНДС / ТаблицаТоваров.Количество
    |    КОНЕЦ КАК Цена,
    |    ТаблицаТоваров.СуммаБезНДС КАК СуммаБезНДС,
    |    ТаблицаТоваров.СуммаНДС КАК СуммаНДС,
    |    ТаблицаТоваров.СуммаБезНДС + ТаблицаТоваров.СуммаНДС КАК СуммаСНДС,
    |    ТаблицаТоваров.МассаНетто,
    |    ТаблицаТоваров.МассаБрутто,
    |    ТаблицаТоваров.НомерСтроки КАК НомерСтроки,
    |    ТаблицаТоваров.НомерСтрокиНаборы КАК НомерСтрокиНаборы,
    |    ВЫБОР
    |        КОГДА
    |            ТаблицаТоваров.Ссылка.ВернутьМногооборотнуюТару
    |            И ТаблицаТоваров.Номенклатура.ТипНоменклатуры = ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.МногооборотнаяТара)
    |        ТОГДА
    |            ИСТИНА
    |        ИНАЧЕ
    |            ЛОЖЬ
    |    КОНЕЦ КАК ЭтоВозвратнаяТара
    |ИЗ
    |(
    |    ВЫБРАТЬ
    |        ТаблицаТоваров.Ссылка,
    |        ВЫБОР КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0 ТОГДА
    |            ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах
    |        ИНАЧЕ
    |            ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ПустаяСсылка)
    |        КОНЕЦ КАК ВариантПредставленияНабораВПечатныхФормах,
    |        ВЫБОР КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0 ТОГДА
    |            ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора
    |        ИНАЧЕ
    |            ЗНАЧЕНИЕ(Перечисление.ВариантыРасчетаЦенНаборов.ПустаяСсылка)
    |        КОНЕЦ КАК ВариантРасчетаЦеныНабора,
    |        ТаблицаТоваров.НоменклатураНабора,
    |        ТаблицаТоваров.ХарактеристикаНабора,
    |        ВЫБОР КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0 ТОГДА
    |            ИСТИНА
    |        ИНАЧЕ
    |            ЛОЖЬ
    |        КОНЕЦ КАК ЭтоКомплектующие,
    |        ЛОЖЬ КАК ЭтоНабор,
    |        ТаблицаТоваров.НомерСтроки КАК НомерСтроки,
    |        ВЫБОР КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0 ТОГДА
    |            ВременнаяТаблицаНаборы.НомерСтроки
    |        ИНАЧЕ
    |            ТаблицаТоваров.НомерСтроки
    |        КОНЕЦ КАК НомерСтрокиНаборы,
    |        ВЫБОР КОГДА ЕСТЬNULL(ВременнаяТаблицаНаборы.НомерСтроки, 0) <> 0 ТОГДА
    |            ВременнаяТаблицаНаборы.ПолныйНабор
    |        ИНАЧЕ
    |            ЛОЖЬ
    |        КОНЕЦ КАК ПолныйНабор,
    |        ТаблицаТоваров.Номенклатура,
    |        ТаблицаТоваров.Количество,
    |        ТаблицаТоваров.КоличествоУпаковок,
    |        ТаблицаТоваров.СтавкаНДС,
    |        ТаблицаТоваров.НомерГТД,
    |        ТаблицаТоваров.СуммаБезНДС,
    |        ТаблицаТоваров.СуммаНДС,
    |        ТаблицаТоваров.Характеристика,
    |        ТаблицаТоваров.Упаковка,
    |        ВЫБОР
    |            КОГДА &ЗаполненаЕдиницаИзмеренияВеса
    |                ТОГДА ВЫБОР
    |                        КОГДА ТаблицаТоваров.Упаковка.Вес ЕСТЬ NULL
    |                            ТОГДА ТаблицаТоваров.Количество
    |                        ИНАЧЕ ВЫБОР
    |                            КОГДА ТаблицаТоваров.Упаковка.ТипИзмеряемойВеличины = Значение(Перечисление.ТипыИзмеряемыхВеличин.Вес)
    |                                ТОГДА 0
    |                            ИНАЧЕ ТаблицаТоваров.КоличествоУпаковок
    |                        КОНЕЦ
    |                    КОНЕЦ * &ТекстЗапросаВесУпаковки
    |            ИНАЧЕ 0
    |        КОНЕЦ КАК МассаБрутто,
    |        ТаблицаТоваров.Количество * &ТекстЗапросаВесНоменклатуры КАК МассаНетто,
    |        ТаблицаТоваров.ЭтоТовар КАК ЭтоТовар
    |    ИЗ
    |        РеализацияТоваровУслугТаблицаТоваров КАК ТаблицаТоваров
    |            ЛЕВОЕ СОЕДИНЕНИЕ ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
    |            ПО ВременнаяТаблицаНаборы.НоменклатураНабора = ТаблицаТоваров.НоменклатураНабора
    |             И ВременнаяТаблицаНаборы.ХарактеристикаНабора = ТаблицаТоваров.ХарактеристикаНабора
    |             И ВременнаяТаблицаНаборы.Ссылка = ТаблицаТоваров.Ссылка
    |
    |    ГДЕ
    |        (ТаблицаТоваров.НоменклатураНабора = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
    |        ИЛИ (ТаблицаТоваров.НоменклатураНабора <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
    |            И ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В (ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоКомплектующие),
    |                                                                                  ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие))))
    |
    |    ОБЪЕДИНИТЬ ВСЕ
    |
    |    ВЫБРАТЬ
    |        ВременнаяТаблицаНаборы.Ссылка,
    |        ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах,
    |        ВременнаяТаблицаНаборы.ВариантРасчетаЦеныНабора КАК ВариантРасчетаЦеныНабора,
    |        ВременнаяТаблицаНаборы.НоменклатураНабора,
    |        ВременнаяТаблицаНаборы.ХарактеристикаНабора,
    |        ЛОЖЬ КАК ЭтоКомплектующие,
    |        ИСТИНА КАК ЭтоНабор,
    |        0 КАК НомерСтроки,
    |        ВременнаяТаблицаНаборы.НомерСтроки КАК НомерСтрокиНаборы,
    |        ВременнаяТаблицаНаборы.ПолныйНабор КАК ПолныйНабор,
    |        ВременнаяТаблицаНаборы.НоменклатураНабора,
    |        ВременнаяТаблицаНаборы.Количество,
    |        ВременнаяТаблицаНаборы.КоличествоУпаковок,
    |        ВременнаяТаблицаНаборы.СтавкаНДС,
    |        ВременнаяТаблицаНаборы.НомерГТД,
    |        ВременнаяТаблицаНаборы.СуммаБезНДС,
    |        ВременнаяТаблицаНаборы.СуммаНДС,
    |        ВременнаяТаблицаНаборы.ХарактеристикаНабора,
    |        ЗНАЧЕНИЕ(Справочник.УпаковкиЕдиницыИзмерения.ПустаяСсылка) КАК Упаковка,
    |        ВременнаяТаблицаНаборы.МассаБрутто,
    |        ВременнаяТаблицаНаборы.МассаНетто,
    |        ИСТИНА КАК ЭтоТовар
    |    ИЗ
    |        ВременнаяТаблицаНаборы КАК ВременнаяТаблицаНаборы
    |    ГДЕ
    |        ВременнаяТаблицаНаборы.ВариантПредставленияНабораВПечатныхФормах В (ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.ТолькоНабор),
    |                                                                            ЗНАЧЕНИЕ(Перечисление.ВариантыПредставленияНаборовВПечатныхФормах.НаборИКомплектующие))
    |) КАК ТаблицаТоваров
    |        ЛЕВОЕ СОЕДИНЕНИЕ КоэффициентыУпаковок КАК КоэффициентыУпаковок
    |        ПО ТаблицаТоваров.Ссылка = КоэффициентыУпаковок.Ссылка
    |            И ТаблицаТоваров.НомерСтроки = КоэффициентыУпаковок.НомерСтроки
    |            И ТаблицаТоваров.КоличествоУпаковок = КоэффициентыУпаковок.КоличествоУпаковок
    |            И НЕ &ВыводитьБазовыеЕдиницыИзмерения
    |ГДЕ
    |    (ТаблицаТоваров.ЭтоТовар
    |            ИЛИ &ВыводитьУслуги)
    |
    |УПОРЯДОЧИТЬ ПО
    |    Ссылка,
    |    НомерСтрокиНаборы,
    |    ЭтоНабор УБЫВ,
    |    НомерСтроки
    |ИТОГИ ПО
    |    Ссылка";

    Запрос.Текст = СтрЗаменить(Запрос.Текст, "&ТекстЗапросаКоэффициентУпаковки",
        Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаКоэффициентаУпаковки(
            "ТаблицаТоваров.Упаковка",
            "ТаблицаТоваров.Номенклатура"));

    Запрос.Текст = СтрЗаменить(
        Запрос.Текст,
        "&ТекстЗапросаВесУпаковки",
        Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки(
            "ТаблицаТоваров.Упаковка",
            "ТаблицаТоваров.Номенклатура"));

    Запрос.Текст = СтрЗаменить(
        Запрос.Текст,
        "&ТекстЗапросаВесНоменклатуры",
        Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаВесУпаковки(
            "ТаблицаТоваров.Номенклатура.ЕдиницаИзмерения",
            "ТаблицаТоваров.Номенклатура"));

    Запрос.Текст = СтрЗаменить(
        Запрос.Текст,
        "&ТекстЗапросаЕдиницаИзмерения",
        Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаЗначениеРеквизитаЕдиницыИзмерения(
            "Ссылка",
            "ТаблицаТоваров.Упаковка",
            "ТаблицаТоваров.Номенклатура"));

    Запрос.Текст = СтрЗаменить(
        Запрос.Текст,
        "&ТекстЗапросаНаименованиеЕдиницыИзмерения1",
        Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаЗначениеРеквизитаЕдиницыИзмерения(
            "Наименование",
            "ТаблицаТоваров.Упаковка",
            "ТаблицаТоваров.Номенклатура"));

    Запрос.Текст = СтрЗаменить(
        Запрос.Текст,
        "&ТекстЗапросаНаименованиеЕдиницыИзмерения2",
        Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаЗначениеРеквизитаЕдиницыИзмерения(
            "Наименование",
            "КоэффициентыУпаковок.ВидУпаковки",
            "ТаблицаТоваров.Номенклатура"));

    Запрос.Текст = СтрЗаменить(
        Запрос.Текст,
        "&ТекстЗапросаКодЕдиницыИзмерения",
        Справочники.УпаковкиЕдиницыИзмерения.ТекстЗапросаЗначениеРеквизитаЕдиницыИзмерения(
            "Код",
            "ТаблицаТоваров.Упаковка",
            "ТаблицаТоваров.Номенклатура"));

    Запрос.УстановитьПараметр("ВыводитьУслуги",                  ПараметрыПечати.ВыводитьУслуги);
    Запрос.УстановитьПараметр("КолонкаКодов",                    КолонкаКодов);
    Запрос.УстановитьПараметр("ЕдиницаИзмеренияВеса",            Константы.ЕдиницаИзмеренияВеса.Получить());
    Запрос.УстановитьПараметр("ЗаполненаЕдиницаИзмеренияВеса",   ЗначениеЗаполнено(Константы.ЕдиницаИзмеренияВеса.Получить()));
    Запрос.УстановитьПараметр("ВыводитьБазовыеЕдиницыИзмерения",
        Константы.ВыводитьБазовыеЕдиницыИзмерения.Получить() ИЛИ ПараметрыЗаполнения.ВключаяНомераГТД);

    МассивРезультатов         = Запрос.ВыполнитьПакет();
    РезультатПоШапке          = МассивРезультатов[0];
    РезультатПоТабличнойЧасти = МассивРезультатов[6];

    СтруктураДанныхДляПечати     = Новый Структура("РезультатПоШапке, РезультатПоТабличнойЧасти",
                                                   РезультатПоШапке, РезультатПоТабличнойЧасти);

    Возврат СтруктураДанныхДляПечати;

КонецФункции

Все работает, но конструктором не открывает как в типовой конфе, так и во внешней обработке.
Ошибка:
Поле не найдено Таблица.Ссылка.ХозяйственнаяОперация (шестой пакет запроса)

И так для многих строк запроса. Я понимаю, что во временную таблицу во втором пакете запроса мы кладем ссылку на табличную часть, а потом пытаемся получить отдельные поля, которые оказываются не найдены. Пробовал во втором пакете выбирать Таблица.Ссылка.ХозяйственнаяОперация, ошибка пропала, но появилась другая.
Поле не найдено ТаблицаТоваров.Номенклатура.НаименованиеПолное.
ТаблицаТоваров - это таблица РеализацияТоваровУслугТаблицаТоваров, которая   есть результат выполнения строки ПродажиСервер.ПоместитьВременнуюТаблицуКоэффициентыУпаковок(МенеджерВременныхТаблиц, "РеализацияТоваровУслугТаблицаТоваров");

Можете подсказать, как с этим быть и как открыть запрос в конструкторе?